capítulo 2 - método dos elementos finitos para treliça 2d
Post on 17-Mar-2022
7 Views
Preview:
TRANSCRIPT
Prof. Luiz Antonio Farani de Souza
1 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Conteúdo Capítulo 2 - Método dos Elementos Finitos para treliça 2D ......................................................... 1
2.1 Introdução ........................................................................................................................... 2
2.2 Formulação de Elementos Finitos para treliça plana .......................................................... 2
2.3 Problema estrutural ............................................................................................................ 4
2.4 Metodologia ........................................................................................................................ 4
2.5 Entendendo a estrutura ...................................................................................................... 5
2.6 Programa de EF para treliça plana ...................................................................................... 6
2.6.1 Passos para criação do programa de elementos finitos para a análise linear de
treliças planas. ....................................................................................................................... 6
2.6.2 Passos para a análise da estrutura (execução do programa). .................................... 11
2.6 Exercícios resolvidos com o programa .............................................................................. 13
Exemplo 1 - Treliça sujeita a uma força .............................................................................. 13
Exemplo 2 - Treliça sujeita a uma força e um deslocamento prescrito no apoio ............... 15
Exemplo 3 - Treliça com um dano em uma das barras ....................................................... 17
2.7 Exercícios propostos .......................................................................................................... 20
Exercício proposto 1. ........................................................................................................... 20
Exercício proposto 2. ........................................................................................................... 20
2.8 Exercícios desafios ............................................................................................................. 21
Exercício desafio 1. .............................................................................................................. 21
Exercício desafio 2. .............................................................................................................. 21
Referências .............................................................................................................................. 22
Prof. Luiz Antonio Farani de Souza
2 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
2.1 Introdução
As treliças são estruturas leves e, por isso, com larga aplicação na construção civil. Elas
são compostas de barras delgadas cujas extremidades são supostamente conectadas por
articulações sem atrito. Se essas são carregadas apenas nos nós, desenvolve-se carregamento axial
em todas as barras. Embora a maioria das ligações de treliça seja formada pela soldagem ou pelo
aparafusamento das extremidades das barras, uma análise da treliça baseada na suposição de
ligações articuladas produz um resultado aceitável (LEET; UANG; GILBERT, 2010; BORGES;
SILVA; BEZERRA, 2016).
A modelagem de treliças planas é feita a partir de elementos finitos de barra com dois
nós. Supõe-se que o material que constitui as barras tenha relação constitutiva elástica linear (ou
seja, obedece à lei de Hooke) e que as suas deformações sejam infinitesimais. Na Figura 2.1 é
ilustrada uma treliça plana usual de cobertura.
Figura 2. 1 Treliça plana. Fonte: Silva Neto et al. (2007).
2.2 Formulação de Elementos Finitos para treliça plana
O elemento de treliça transmite somente forças axiais N e tem área da seção transversal
constante A. Os nós “1” e “2” do elemento têm coordenadas (X1, Y1) e (X2, Y2) no sistema global
cartesiano, repectivamente, e representam a configuração inicial do elemento de barra (também
conhecida como coordenadas de referência). Após uma mudança de configuração da treliça
devido a deslocamentos causados por um carregamento externo, a barra passa a ter novas
coordenadas (x1, y1) e (x2, y2). O comprimento inicial (ou referencial) L0 e o comprimento final
(ou deformado) L da barra são calculados, respectivamente, por (ZIENKIEWICZ; TAYLOR;
ZHU, 2005; BATHE, 2016):
L0 = √(X2 − X1)2 + (Y2 − Y1)2, (2.1)
L = √(x2 − x1)2 + (y2 − y1)2. (2.2)
Um desenho esquemático do elemento de treliça 2D aparece na Figura 2.2. O ângulo
inicial desse elemento com relação ao sistema de coordenadas globais é denotado por .
Figura 2. 2 Elemento de treliça 2D - coordenadas local e global. Fonte: adaptada de Silva
Neto et al. (2007).
Prof. Luiz Antonio Farani de Souza
3 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Na formulação bidimensional, os valores do seno e cosseno desse ângulo são
determinados por, respectivamente:
cos(θ) =X2 − X1
L0 (2.3)
sen(θ) =Y2 − Y1
L0 (2.4)
O vetor de deslocamentos nodais p no sistema global de coordenadas de um elemento de
treliça 2D é:
𝐩 = [u1 v1 u2 v2]T (2.5)
na qual ui e vi, com i = 1, 2, são os deslocamentos horizontais e verticais, repectivamente. A
relação entre as componentes de deslocamentos nos sistemas global e local de coordenadas é dada
por:
[
u1
v1u2
v2
] = 𝐓 [
ul1
vl1ul2
vl2
] (2.6)
na qual T é a matriz de transformação representada por:
𝐓 = [
cos(θ) −sen(θ)
sen(θ) cos(θ)0 00 0
0 00 0
cos(θ) −sen(θ)
sen(θ) cos(θ)
] (2.7)
A matriz de rigidez elementar kel é obtida no sistema local de coordenadas por:
𝐤𝐞𝐥 =EA
L0𝐁 (2.8)
na qual E é o módulo de elasticidade longitudinal e B é a matriz dada por:
𝐁 = [
1 00 0
−1 0 0 0
−1 00 0
1 0 0 0
] (2.9)
A matriz de rigidez elementar no sistema global de coordenadas Kel é calculada por:
𝐊𝐞𝐥 = 𝐓𝐤𝐞𝐥𝐓T (2.10)
O vetor de forças internas elementar no sistema local de coordenadas fel é obtido por:
𝐟𝐞𝐥 =EAεE
L0𝐫 (2.11)
em que r é um vetor dado por:
𝐫 = [
−cos(θ)
−sen(θ)
cos(θ)
en(θ)
] (2.12)
e εE é deformação específica de Engenharia calculada pela expressão:
εE =ul2 − ul1
L0 (2.13)
O vetor de forças internas elementar no sistema global de coordenadas Fel é determinado
por:
Prof. Luiz Antonio Farani de Souza
4 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
𝐅𝐞𝐥 = 𝐓𝐟𝐞𝐥 (2.14)
2.3 Problema estrutural
O sistema de equações lineares que representa o equilíbrio estático da estrutura é:
𝐊𝐮 = 𝐅𝐞𝐱𝐭 (2.15)
em que u é vetor de deslocamentos nodais, K é a matriz de rigidez da estrutura no sistema global
de coordenadas (gerada pelo Método dos Elementos Finitos) e Fext é o vetor de forças externas
(ZIENKIEWICZ; TAYLOR; ZHU, 2005; BATHE, 2016).
A matriz de rigidez K é obtida por:
𝐊 = ∑ 𝐊𝐞𝐥𝐞
n
e=1
(2.16)
em que e é o elemento finito e n é o número total de elementos da treliça.
2.4 Metodologia
Utilizando o programa livre Scilab versão 6.1.1 (SCILAB, 2021), realiza-se a
implementação do elemento de barra 2D para análise linear estática de treliças planas.
Inicialmente, o programa faz a leitura dos dados de entrada. O usuário deve fornecer ao
software todas as informações necessárias acerca da estrutura a ser analisada. Essas informações
(sequencialmente) são:
• Número total de nós;
• Número total de barras;
• Número total de graus de liberdade da estrutura;
• Número de graus de liberdade restringidos (condições de contorno);
• Posição dos nós (coordenadas no sistema de referência X, Y);
• Conectividades dos nós com as barras (incidência dos elementos);
• Cargas atuantes, indicando o nó e o grau de liberdade (vetor de força externa Fext); e
• Área da seção transversal A e o módulo de elasticidade E de cada barra.
Fazendo-se o uso dos dados de entrada, o programa processa-os e calcula as matrizes de
rigidez de cada elemento Kel (Equação (2.10)) Essas matrizes são então usadas para montar a
matriz de rigidez global do sistema estrutural K (Equação (2.16)).
O próximo passo é a aplicação das condições de contorno do problema. Essas condições
são pré-estabelecidas nos dados de entrada. Dessa forma, tem-se um sistema de equações lineares
(Ku = Fext) com uma matriz de rigidez não singular (a inversa de K existe). Com a solução desse
sistema, obtêm-se os valores dos deslocamentos nodais u. Posteriormente, o programa calcula a
deformação específica , a tensão normal e a força normal de cada elemento. Essas grandezas
são consideradas constantes ao longo da seção transversal para um elemento de barra. Por fim, o
código determina as reações nos apoios. A Figura 2.3 apresenta o fluxograma de montagem do
código computacional.
Prof. Luiz Antonio Farani de Souza
5 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Figura 2. 3 Fluxograma de montagem do código computacional. Fonte: adaptada de
Borges, Silva e Bezerra (2016).
2.5 Entendendo a estrutura
O modelo estrutural deve conter informações sobre dimensão e apoios da estrutura, as
forças externas aplicadas e as propriedades materiais e geométricas das barras.
Como o tipo de estrutura a ser analisado é a treliça plana, as dimensões são definidas
com base no sistema global de coordenadas cartesianas bidimensionais (eixo de coordenadas
horizontais X e eixo de coordenadas verticais Y).
Os apoios admitidos para a estrutura são os de primeiro gênero (rolete) e de segundo
gênero (pino). Os carregamentos são forças concentradas aplicadas nos nós da mesma.
As propriedades materiais e geométricas das barras da treliça são: módulo de elasticidade
longitudinal E e área da seção transversal A. Essas propriedades podem ser definidas com
diferentes valores para barras distintas da estrutura.
Com o modelo da estrutura definido, a mesma é discretizada por elementos finitos. Cada
barra da treliça é um elemento finito (descrito na Seção 2.2), e este possui dois nós que definem
o seu início (i) e o seu final (j), conforme o desenho esquemático da Figura 2.4.
Figura 2. 4 Elemento de barra e seus componentes de deslocamento e de força. Fonte:
adaptada de Alves Filho (2000).
Prof. Luiz Antonio Farani de Souza
6 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Deve-se observar, na treliça da Figura 2.4, que um mesmo nó pertence a mais de um
elemento, sendo que os nós são os responsáveis pela conectividade da estrutura. Cada elemento
de barra possui dois nós - um nó inicial (i) e um final (j) -, com dois graus de liberdade por nó
(deslocamento horizontal u e deslocamento vertical v). Cada elemento possui o seu próprio
sistema local de coordenadas (xl, yl) que, usualmente, são distintos do sistema global de
coordenadas (X, Y), em que toda estrutura é definida.
Ressalta-se que, apesar dos elementos de barra possuírem sistemas de eixos de
coordenadas locais, todos os dados do modelo estrutural (coordenadas nodais, forças externas,
etc.) são definidos no sistema global de coordenadas, uma vez que vale para toda estrutura e é
com base nesse sistema que a função de entrada de dados é criada.
2.6 Programa de EF para treliça plana
2.6.1 Passos para criação do programa de elementos finitos para a análise linear de treliças planas.
1. Fazer o download do programa Scilab disponível no endereço
https://www.scilab.org/download/6.1.1.
2. Criar uma pasta com o nome do programa (por exemplo, "trelica2D").
3. Dentro dessa pasta, criar no Scilab os arquivos programa principal (principal.sce) e as
funções (com extensão .sci), utilizando o SciNotes.
Importante:
- As funções deverão ser salvas com a extensão .sci e o programa principal com a extensão
.sce; e
- Salvar a função num arquivo com o mesmo nome.
• programa principal: principal.sce //programa principal - treliça 2D
//Análise linear
//limpa da memória as variáveis
clear
//limpa a janela de comandos (console)
clc
funcprot(0)
//_____________________________________
//inicialização das funções (.sci)
exec('DKG.sci',-1);
exec('dkelem.sci',0);
exec('dfelem.sci',0);
exec('ensamkg.sci',-1);
exec('contkg.sci',-1);
exec('apontador.sci',-1);
exec('entrada_dados.sci',-1);
exec('ensamfg.sci',-1);
exec('contfg.sci',-1);
Prof. Luiz Antonio Farani de Souza
7 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
//_____________________________________
//entrada de dados
[NTNOS,NTEL,NNOSCC,NTGL,coord,inci,dofno,Fext,NOCC,E,A,itipo]=entrada_dados();
//_____________________________________
//Processamento
//Monta a matriz de rigidez K
[K]=DKG(NOCC,NNOSCC,NTGL,NTEL,dofno,inci,coord,E,A,itipo);
//Resolução do sistema de equações lineares
u=K\Fext;
//_____________________________________
//Saída de dados
//Imprime no console os deslocamentos nos nós da treliça:
for i=1:NTNOS
vu(i,1)=i;
vu(i,2)=u(2*i-1,1);
vu(i,3)=u(2*i,1);
end
disp('1) Deslocamentos nos nós da treliça:')
disp(vu)
[N,eps,Sigma,R,FG,L]=dfelem(NTEL,NTGL,NOCC,E,A,inci,u,dofno,coord,itipo);
//Imprime no console as deformações, tensões e forças normais nas barras da treliça:
for i=1:NTEL
vm(i,1)=i;
vm(i,2)=eps(i);
vm(i,3)=Sigma(i);
vm(i,4)=N(i);
end
disp('2) Deformações, tensões e forças normais nas barras da treliça:')
disp(vm)
//Imprime no console as reações nos apoios:
disp('3) Reações nos apoios da treliça:')
for i=1:length(NOCC)/2
disp('apoio',i,R(2*i-1),R(2*i));
end
• função: apontador.sci function [IPO, TAM]=apontador(m, itipo)
//Elemeno de barra com 2 NÓS, 2GL/NÓ
if (itipo(m,2)==1) then
IPO(1)=1;
IPO(2)=2;
IPO(3)=3;
IPO(4)=4;
TAM=4;
end
endfunction
• função: contkg.sci function [KG]=contkg(NOCC, NNOSCC, NTGL, KG)
for J=1:NNOSCC
for I=1:NTGL
KG(NOCC(1,J),I)=0;
KG(I,NOCC(1,J))=0;
end
KG(NOCC(1,J),NOCC(1,J))=1;
end
Prof. Luiz Antonio Farani de Souza
8 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
endfunction
• função: dfelem.sci function [N, eps, Sigma, R, FG, L]=dfelem(NTEL, NTGL, NOCC, E, A, inci, u, dofno, coord,
itipo)
//determina as deformações, tensões e forças normais nas barras e as reações nos apoios da treliça
//determina o vetor de força interna global
//determina os comprimentos deformados das barras
FG=zeros(NTGL,1);
for m=1:NTEL
for i=1:4
ul(i)=u(dofno(m,i),1); //seleciona os deslocamentos nos nós da barra m
end
X1=coord(inci(m,2),1); //coordenada X do nó 1
X2=coord(inci(m,3),1); //coordenada Y do nó 1
Y1=coord(inci(m,2),2); //coordenada X do nó 2
Y2=coord(inci(m,3),2); //coordenada Y do nó 2
L0(m)=sqrt((X2-X1)^2+(Y2-Y1)^2); //comprimento indeformado
L(m)=sqrt((X2+ul(3)-X1-ul(1))^2 + (Y2+ul(4)-Y1-ul(2))^2 ); //comprimento deformada
c=(X2-X1)/L0(m); //cosseno de teta
s=(Y2-Y1)/L0(m); //seno de teta
T = [c s 0 0; //matriz de transformação
-s c 0 0;
0 0 c s;
0 0 -s c];
r=[-c;-s;c;s]; //vetor r
ul=T*ul; //transformação dos deslocamentos da referência global para a local
eps(m)=(ul(3)-ul(1))/(L0(m)); //deformação de engenharia da barra m
N(m) = E(m)*A(m)*eps(m); //força normal da barra m
Sigma(m)= E(m)*eps(m); //tensão normal da barra m
FELEM = N(m)*r; //vetor de força interna elementar
[FG]=ensamfg(m,FELEM,dofno,itipo,FG) //monta o vetor de força interna global (FG)
end
n=length(NOCC);
for j=1:n
R(j)=FG(NOCC(j)); //reações (forças) nos apoios
end
[FG]=contfg(NOCC,NNOSCC,FG); //impõe as condições de contorno no vetor FG
endfunction
• função: dkelem.sci function [KELEM]=dkelem(m, E, A, inci, dofno, coord)
//Determina matriz de rigidez elementar da barra m
KELEM=zeros(4,4);
X1=coord(inci(m,2),1); //coordenada X do nó 1
X2=coord(inci(m,3),1); //coordenada Y do nó 1
Y1=coord(inci(m,2),2); //coordenada X do nó 2
Y2=coord(inci(m,3),2); //coordenada Y do nó 2
L0(m)=sqrt((X2-X1)^2+(Y2-Y1)^2); //comprimento indeformado
c=(X2-X1)/L0(m); //cosseno de teta
s=(Y2-Y1)/L0(m); //seno de teta
T = [c s 0 0; //matriz de transformação
-s c 0 0;
0 0 c s;
0 0 -s c];
B=[1 0 -1 0; //matriz B
0 0 0 0;
-1 0 1 0;
0 0 0 0];
Ke = E(m)*A(m)/L0(m)*B; //matriz de rigidez da barra m no sistema local
Prof. Luiz Antonio Farani de Souza
9 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
KELEM=T'*Ke*T; //matriz de rigidez da barra m no sistema global
endfunction
• função: DKG.sci function [K]=DKG(NOCC, NNOSCC, NTGL, NTEL, dofno, inci, coord, E, A, itipo)
//Determina a matriz de rigidez global (K)
K=zeros(NTGL,NTGL);
for m=1:NTEL
[KELEM]=dkelem(m,E,A,inci,dofno,coord);
[K]=ensamkg(m,KELEM,dofno,itipo,K);
end
[K]=contkg(NOCC,NNOSCC,NTGL,K);
endfunction
• função: ensamkg.sci function [KG]=ensamkg(m, KELEM, dofno, itipo, KG)
[IPO,TAM]=apontador(m,itipo);
for I=1:TAM
for J=1:TAM
P=dofno(m,IPO(I));
Q=dofno(m,IPO(J));
if (P>0 & Q>0)
KG(P,Q)=KG(P,Q)+KELEM(I,J);
end
end
end
endfunction
• função: entrada_dados.sci function [NTNOS, NTEL, NNOSCC, NTGL, coord, inci, dofno, Fext, NOCC, E, A,
itipo]=entrada_dados()
//Informa os dados da malha de elementos finitos, vetor de força e propriedades materiais e
geométricas das barras
//NTNOS -> NÚMERO TOTAL DE NÓS
//NTEL -> NÚMERO TOTAL DE ELEMENTOS
//NTGL -> NÚMERO TOTAL DE GRAUS DE LIBERDADE
//NNOSCC -> NÚMERO DE GRAUS RESTRITOS (CONDIÇÕES DE CONTORNO)
NTNOS=4; //informar
NTEL=4; //informar
NNOSCC=4; //informar
NTGL=NTNOS*2;
//Informa as coordenadas dos nós (informar a matriz)
//coord(i,1)= coordenada x
//coord(i,2)= coordenada y
coord=[0 0;
4 0;
0 2;
2 2];
//Informa a incidência dos elementos (informar a matriz)
//inci(i,1) = elemento
//inci(i,2) = nó i
//inci(i,3) = nó j
inci=[1 1 2 ;
2 1 4 ;
3 2 4 ;
4 3 4 ];
//informa os graus de liberdade por nó
for I=1:NTEL
//elemento de treliça 2D
dofno(I,1)=inci(I,2)*2-1; //NÓ I
Prof. Luiz Antonio Farani de Souza
10 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
dofno(I,2)=inci(I,2)*2;
dofno(I,3)=inci(I,3)*2-1; //NÓ J
dofno(I,4)=inci(I,3)*2;
end
//elemento barra -> itipo(nel,2)==1
//elemento viga -> itipo(nel,2)==2
//material 1 -> itipo(nel,3)==1
//material 2 -> itipo(nel,3)==2
for i=1:NTEL
itipo(i,1) = i;
itipo(i,2) = 1;
itipo(i,3) = 1;
end
//propriedades materiais e geométricas das barras
for m=1:NTEL
if itipo(m,3)==1
E(m)=200*10^6; //informar o módulo de elasticidade
A(m)=400*10^-6; //informar a área da seção transversal da barra
end
end
//vetor de força externa Fext
Fext=zeros(NTGL,1);
//informar as forças (carregamento) nos graus de liberdade
Fext(2*2,1)=-100;
//informar as condições de contorno (graus de liberdade restringidos)
NOCC=[1 2 5 6]; //informar os graus de liberdade restringidos
endfunction
• função: ensamfg.sci function [FG]=ensamfg(m, FELEM, dofno, itipo, FG)
//monta o vetor de força interna global
[IPO,TAM]=apontador(m,itipo);
for I=1:TAM
P=dofno(m,IPO(I));
if (P>0)
FG(P,1)=FG(P,1)+FELEM(I,1);
end
end
endfunction
• função: contfg.sci function [FG]=contfg(NOCC, NNOSCC, FG)
//impõe as condições de contorno no vetor de força interna global
for I=1:NNOSCC
FG(NOCC(1,I))=0;
end
endfunction
Prof. Luiz Antonio Farani de Souza
11 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
2.6.2 Passos para a análise da estrutura (execução do programa).
1. Executar o programa Scilab .
2. Selecionar a pasta que contém os arquivos do programa de EF criado (botão "Selecione
um diretório").
3. Inserir os dados de entrada da estrutura (malha de elementos finitos, propriedades
geométricas e materiais das barras e vetor de força externa) na função entrada_dados.sci. As
seguintes informações devem ser colocadas nessa função:
a) Informar:
NTNOS → número total de nós
NTEL → número total de elementos
NTGL → número total de graus de liberdade
NNOSCC → número de graus de liberdade restringidos (condições de contorno)
b) coordenadas dos nós (matriz coord);
c) incidência dos elementos (matriz inci);
d) tipo do elemento e tipo de material (matriz itipo);
e) propriedades de cada barra: módulo de elasticidade E e área da seção transversal A;
f) vetor de força externa (Fext) - indicar as forças (cargas) nos graus de liberdade;
g) informar os graus de liberdade restringidos (apoios) (vetor NOCC).
4. Executar o programa.
Prof. Luiz Antonio Farani de Souza
12 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
5. Os resultados numéricos (deslocamentos nos nós, deformações, tensões e forças
normais nas barras e reações nos apoios) são imprimidos no Console (janela de comandos).
Prof. Luiz Antonio Farani de Souza
13 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
2.6 Exercícios resolvidos com o programa
Nesta seção são apresentados exemplos numéricos de treliças planas, em que são
realizadas análises estáticas lineares (material no regime elástico linear e hipótese de deformações
infinitesimais) por meio do programa de Elementos Finitos desenvolvido no programa Scilab
versão 6.1.1 (ver Seção 2.6). São considerados três problemas: treliça sujeita a uma força; treliça
sujeita a uma força e um deslocamento prescrito no apoio; e treliça com um dano numa das barras.
Exemplo 1 - Treliça sujeita a uma força
Seja a treliça plana de aço ilustrada na Figura 2.5 com quatro nós e sujeita a uma força de
intensidade 100 kN, proposta por Hibbeler (2004). As barras têm área da seção transversal A =
400 mm2 e módulo de elasticidade longitudinal E = 200 GPa. Determinar:
a) os deslocamentos dos nós;
b) as deformações específicas, as tensões normais e as forças normais nas barras; e
c) as reações nos apoios.
Coordenadas nodais Incidência dos elementos
nó X (m) Y (m) Elemento Nó i Nó j
1 0 0 1 1 2
2 4 0 2 1 4
3 0 2 3 2 4
4 2 2 4 3 4
Figura 2. 5 Modelo estrutural da treliça com quatro nós.
• Dados de entrada (função - entrada_dados.sci):
Dados da malha Coordenadas
dos nós
Incidência
dos
elementos
Tipo do elemento
Propriedades geométrica e
material das
barras
NTNOS=4;
NTEL=4;
NNOSCC=4;
coord=[0 0;
4 0;
0 2;
2 2];
inci=[1 1
2 ;
2 1 4 ;
3 2 4 ;
4 3 4 ];
for i=1:NTEL
itipo(i,1) = i;
itipo(i,2) = 1;
itipo(i,3) = 1;
end
for m=1:NTEL
if itipo(m,3)==1
E(m)=200*10^6;
A(m)=400*10^-6;
end
end
Vetor força externa Graus de liberdade
restringidos
Fext=zeros(NTGL,1);
Fext(2*2,1)=-100;
NOCC=[1 2 5 6];
Prof. Luiz Antonio Farani de Souza
14 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Solução:
Na Tabela 2.1 aparecem os valores do deslocamento vertical no nó 4 (em metros) obtidos
por: programa de EF desenvolvido, Método das Forças Virtuais e Ftool (FTOOL, 2018). Na
Tabela 2.2 são apresentadas as forças reativas (em kN) nos apoios.
Tabela 2. 1 Comparação do deslocamento vertical v no nó 4.
Método/Programa v (m)
Ftool -0,01207
Método das Forças Virtuais (Hibbeler, 2004) -0,01207
Programa Scilab -0,0120711
Tabela 2. 2 Reações nos apoios (kN).
Programa de EF Ftool
200 200 →
100 100
-200 200
0 0
Observação: convenção de sinais para as reações (forças) nos apoios:
Sentidos positivos: →.
• Resultados numéricos no Console do Scilab:
Prof. Luiz Antonio Farani de Souza
15 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Exemplo 2 - Treliça sujeita a uma força e um deslocamento prescrito no apoio
Para o problema da treliça do Exemplo 1, considere um recalque = 0,01 com sentido
para baixo no apoio do nó 3 (Figura 2.6). Determinar:
a) os deslocamentos dos nós; e
b) as deformações, as tensões normais e forças normais nas barras.
Figura 2. 6 Modelo estrutural da treliça.
• Programa principal (consideração do recalque): principal.sce //programa principal - treliça 2D
//Análise linear
//limpa da memória as variáveis
clear
//limpa a janela de comandos (console)
clc
funcprot(0)
//_____________________________________
//inicialização das funções (.sci)
exec('DKG.sci',-1);
exec('dkelem.sci',0);
exec('dfelem.sci',0);
exec('ensamkg.sci',-1);
exec('contkg.sci',-1);
exec('apontador.sci',-1);
exec('entrada_dados.sci',-1);
exec('ensamfg.sci',-1);
exec('contfg.sci',-1);
//_____________________________________
//entrada de dados
[NTNOS,NTEL,NNOSCC,NTGL,coord,inci,dofno,Fext,NOCC,E,A,itipo]=entrada_dados();
//deslocamento prescrito (recalque)
desl_presc=zeros(NTGL,1); // Criação do vetor desl_presc Criação do vetor de
desl_presc(2*3,1) = .01; // Deslocamento vertical prescrito no nó 3 deslocamentos prescritos
//Processamento
//Monta a matriz de rigidez
[K]=DKG(NOCC,NNOSCC,NTGL,NTEL,dofno,inci,coord,E,A,itipo);
//Resolução do sistema de equações lineares
u=K\(Fext-K*desl_presc); // Inserção do vetor KG*desl_presc Sistema a ser resolvido
//Saída de dados
//Imprime no console os deslocamentos nos nós da treliça:
for i=1:NTNOS
vu(i,1)=i;
vu(i,2)=u(2*i-1,1);
vu(i,3)=u(2*i,1);
end
disp('1) Deslocamentos nos nós da treliça:')
Prof. Luiz Antonio Farani de Souza
16 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
disp(vu)
[N,eps,Sigma,R,FG,L]=dfelem(NTEL,NTGL,NOCC,E,A,inci,u,dofno,coord,itipo);
//Imprime no console as deformações, tensões e forças normais nas barras da treliça:
for i=1:NTEL
vm(i,1)=i;
vm(i,2)=eps(i);
vm(i,3)=Sigma(i);
vm(i,4)=N(i);
end
disp('2) Deformações, tensões e forças normais nas barras da treliça:')
disp(vm)
//Imprime no console as reações nos apoios:
disp('3) Reações nos apoios da treliça:')
for i=1:length(NOCC)/2
disp('apoio',i,R(2*i-1),R(2*i));
end
Solução:
• Resultados numéricos no Console do Scilab:
Na Tabela 2.3 são mostrados os deslocamentos nodais (em metros) e as forças normais
nas barras (em kN), obtidos pelo programa de EF desenvolvido e o programa Ftool (FTOOL,
2018).
Tabela 2. 3 Resultados dos deslocamentos nos nós e forças normais nas barras.
Prof. Luiz Antonio Farani de Souza
17 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Deslocamentos nos nós
Nó Programa de EF Ftool
u (m) v (m) u (m) v (m)
1 0 0 0 0
2 -0.005 -0.0291421 -0.005 -0.02914
3 0 -0.01 0 -0.01
4 0.005 -0.0120711 0.005 -0.01207
Força normal (kN)
Barra Programa de EF Ftool
1 -100 -100
2 -141.42136 -141.4214
3 141.42136 141.4214
4 200 200
Exemplo 3 - Treliça com um dano em uma das barras
Considere a treliça plana na Figura 2.7 com 5 nós e 7 elementos, cujas barras têm área da
seção transversal A = 25 cm2 e módulo de elasticidade E0 = 100 GPa. Considere um dano na barra
"5" d = 0,4, de forma que o módulo de elasticidade para essa barra seja E = (1-d) E0. Determinar:
a) os deslocamentos dos nós;
b) forças normais nas barras; e
c) as reações nos apoios.
Coordenadas nodais
nó X (m) Y (m)
1 0 0
2 4 0
3 8 0
4 4 4
5 8 4
Incidência dos elementos
elem. Nó i Nó j
1 1 2
2 2 3
3 1 4
4 2 4
5 3 4
6 3 5
7 4 5
Figura 2. 7 Modelo estrutural da treliça
Prof. Luiz Antonio Farani de Souza
18 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
• Dados de entrada (função: entrada_dados.sci):
Dados da malha Coordenadas
dos nós
Incidência
dos
elementos
Tipo do elemento
Propriedades geométrica e
material das
barras
NTNOS=5;
NTEL=7;
NNOSCC=4;
coord=[0 0;
4 0;
8 0;
4 4;
8 4];
inci=[1 1
2;
2 2 3;
3 1 4;
4 2 4;
5 3 4;
6 3 5;
7 4 5];
for i=1:NTEL
itipo(i,1) = i;
itipo(i,2) = 1;
itipo(i,3) = 1;
end
for i=5:5
itipo(i,1) = i;
itipo(i,2) = 1;
itipo(i,3) = 2;
end
for m=1:NTEL
if itipo(m,3)==1
E(m)=100*10^6;
A(m)=25*10^-4;
end
if itipo(m,3)==2
E(m)=(1-
0.4)*100*10^6;
A(m)=25*10^-4;
end
end
Vetor força externa Graus de liberdade
restringidos
Fext=zeros(NTGL,1);
Fext(4*2-1,1)=50;
Fext(4*2,1)=-120;
Fext(5*2-1,1)=-30;
NOCC=[1 2 5 6];
Solução:
• Resultados numéricos no console do Scilab:
Prof. Luiz Antonio Farani de Souza
19 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Na Tabela 2.4 são mostrados os deslocamentos nodais (em metros) e as forças normais
nas barras (em kN), obtidos pelo programa de EF desenvolvido e pelo programa Ftool (FTOOL,
2018). Na Tabela 2.5 são apresentadas as forças reativas (em kN) nos apoios.
Tabela 2. 4 Resultados dos deslocamentos nos nós e forças normais nas barras.
Deslocamentos nos nós
Nó Programa de EF Ftool
u (m) v (m) u (m) v (m)
1 0 0 0 0
2 0 -0.0037712 0 -3.771e-03
3 0 0 0 0
4 0.0015085 -0.0037712 1.508e-03 -3.771e-03
5 0.0010285 0 1.028e-03 0
Força normal (kN)
Barra Programa de EF Ftool
1 0 0
2 0 0
3 -70.710678 -70.7107
4 0 0
5 -98.994949 -98.9949
6 0 0
7 -30 -30.0000
Tabela 2. 5 Reações nos apoios (kN).
Programa Ftool
50 50 →
50 50
-70 70
70 70
Observação: convenção de sinais para as reações (forças) nos apoios:
Sentidos positivos: →.
Na Figura 2.8 são apresentadas as forças normais e as forças reativas nos apoios (em kN)
obtidas no programa Ftool (FTOOL, 2018).
Figura 2. 8 Ftool - reações nos apoios e forças normais nas barras.
Prof. Luiz Antonio Farani de Souza
20 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
2.7 Exercícios propostos
Resolver os exercícios de treliças planas a seguir utilizando o código de elementos finitos
para treliça plana desenvolvido no programa Scilab (ver seção 2.6).
Exercício proposto 1. Determinar o deslocamento vertical (em mm) no ponto B. Cada elemento
tem área da seção transversal A = 400 mm2 e todos são feitos de aço A-36 (E = 200 GPa)
(HIBBELER, 2004).
Resposta: vB = 3,79 mm
Exercício proposto 2. Determinar as forças normais nos elementos GF, CF e CD para a treliça
de ponte e indique se elas estão sob tração ou compressão. Cada elemento tem área da seção
transversal A = 300 mm2 e todos são feitos de aço A-36 (E = 200 GPa) (HIBBELER, 2005).
Resposta: NGF = 29,0 kN (C); NCF = 7,78 kN (T); NCD = 23,5 kN (T)
Prof. Luiz Antonio Farani de Souza
21 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
2.8 Exercícios desafios
Exercício desafio 1. Seja a treliça com 8 nós e considere que todas as barras têm diâmetro d =
2 pol e módulo de elasticidade E = 29 103 kip/pol2. Qual a maior intensidade da carga P em kip
que pode ser suportada pela treliça sem provocar flambagem em nenhuma das barras? Suponha
que as barras da treliça falhem quando a força normal for igual à força crítica de flambagem.
Considere 1 pé = 12 polegadas.
A carga crítica de flambagem é obtida pela equação:
Pcr =π2EI
L02 (2.17)
na qual L0 é o comprimento indeformado da barra e I é momento de inércia da seção em relação
ao centro geométrico.
Exercício desafio 2. Seja a treliça com 5 nós e considere que todas as barras têm diâmetro d =
5 mm, módulo de elasticidade E = 20500 kN/cm2 e tensão de escoamento Y = 5,0 kN/cm2. Qual
a maior carga P (em kN) que pode ser aplicada na estrutura sem que nenhuma barra falhe devido
à tensão de escoamento ou por flambagem? Considere que o deslocamento máximo na treliça não
pode ser superior a vão/200 = 5 m/200 = 0,025 m.
Prof. Luiz Antonio Farani de Souza
22 Capítulo 2 - Método dos Elementos Finitos para treliça 2D
Programa no Scilab
Referências
ALVES FILHO, A. Elementos Finitos: A Base da Tecnologia CAE. São Paulo: Érica, 2000.
BATHE, K. J. Finite element procedures. 2ª Ed. Watertown, MA: Klaus-Jurgen Bathe, 2016.
BORGES, R. A.; SILVA, S. S.; BEZERRA, A. A. B. Estudo de treliças planas e espaciais
utilizando a linguagem de programação Python e o software VTK. In: XXXVII Iberian Latin
American Congress on Computational Methods in Engineering, Brasília, Brasil, 2007. Anais...
Brasília: XXXVII CILAMCE, 2016.
FTOOL, version 4.00.04. Pontifícia Universidade Católica, Tecgraf/PUC-Rio, Rio de Janeiro,
2018.
HIBBELER, R. C. Resistência dos Materiais. Ed. São Paulo: Pearson Education do Brasil, 2004.
HIBBELER, R. C. Estática: mecânica para engenharia. São Paulo: Pearson Education do
Brasil, 2005.
LEET, K. M.; UANG, C. M.; GILBERT, A. M. Fundamentos da Análise Estrutural. 3ª ed.
Porto Alegre: AMGH, 2010.
SCILAB, versão 6.1.1. ESI Group, 2021.
SILVA NETO, G. C.; LOPES, R. C.; LOPES, A. P. O método dos elementos finitos em treliças
planas na disciplina de mecânica computacional. In: XXXV Congresso Brasileiro de Ensino de
Engenharia, Curitiba, Brasil, 2007. Anais... Curitiba: XXXV COBENGE, 2007.
ZIENKIEWICZ, O. C.; TAYLOR, R. L.; ZHU, J. Z. The finite element method: its basis and
fundamentals. Elsevier, 2005.
top related